Japanese Characters in LSS files

HCL Domino Domino Forum
1

I have created an lss file which I would like to add a messagebox with Japanese text. I created the lss file in notepad but when I save it it asks me what Encoding; Unicode or UTF-8. When I use either Unicode or UTF-8 I get an error when I compile it in my Notes LotusScript action button… What am I doing wrong, should I be using a different editor? I did try word pad and it changed the text to ???. I need the lss file to hide code from other users… Thanks

2

Subject: RE: Japanese Characters in LSS files

It seems your operating system default is to use ASCII in text files. The LotusScript compiler will assume the files are stored in the operating system default character set – there’s no file header in Windows telling the type of the contents.

I suggest you convert your message characters to the unicode numbers so that you can store them in the lowest common denominator, ASCII. Here’s some code that allows you to input message text and converts it to an ASCII representation that you can paste into your code.

Dim strOriginal As String, strEncoded As String, strCur As String

Dim lngPos As Long

Dim lngUni As Long

Dim boolInQuotes As Boolean

strOriginal = Inputbox$("Enter a string to convert to ASCII representation" , "UniCoder", {He said, "私を許しなさい。"})

If strOriginal <> "" Then

	For lngPos = 1 To Len(strOriginal)

		strCur = Mid$(strOriginal, lngPos, 1)

		lngUni = Uni(strCur)

		If lngUni < 32 Or lngUni > &h7f Then

			If boolInQuotes Then

				strEncoded = strEncoded & {" & uchr$(} & lngUni & {)}

				boolInQuotes = False

			Else

				If strEncoded <> "" Then strEncoded = strEncoded & { & }

				strEncoded = strEncoded & {uchr$(} & lngUni & {)}

			End If

		Else

			If Not boolInQuotes Then

				boolInQuotes = True

				If strEncoded = "" Then

					strEncoded = {"}

				Else

					strEncoded = strEncoded & { & "}

				End If

			End If

			If strCur = {"} Then

				strEncoded = strEncoded & {""}

			Else

				strEncoded = strEncoded & strCur

			End If

		End If

	Next

End If

If boolInQuotes Then strEncoded = strEncoded & {"}



Msgbox strEncoded, 0, "UniCoder"

strOriginal = Inputbox$("Here's the string to copy and paste:" , "UniCoder", strEncoded)
3

Subject: RE: Japanese Characters in LSS files

Thanks for your help I will give that a try…