Problem with rules

HCL Domino Domino Forum
1

hello

I disable a rule in my mail but it is still running on the server

So I deleted the rule but it is always the same

Have you a solution to see ghosts rules on Notes clients or view all the rules of Lotus customers on the server

Thank you for your return

Olivier Picard

2

Subject: to refresh the rule

The server may take some to refresh it. You may try to create a dummy rule, then delete it to refresh the rule.

3

Subject: forwarded to development <eom.

mh/sjc

4

Subject: This is probably an old issue…

Search the Notes 6 forum for more info, but this is probably another old issue that’s never been resolved.

This is a button agent I send to users with this issue, it removes all the rules.

Sub Click(Source As Button)

Dim session As New NotesSession

Dim db As NotesDatabase

Set db = session.currentdatabase

Dim workspace As New NotesUIWorkspace

'This folder contains all the Mail Rules.

Dim folder As NotesView

Set folder = db.GetView("(Rules)")

'Find the calendar profile document in the current database. (GetProfileDocument will create the named profile document if it does not already exist.)

Dim calendarProfile As NotesDocument

Set calendarProfile = db.GetProfileDocument( "CalendarProfile" )

'Mail Rules are compiled and saved in special fields named $FilterFormula_xx

'Remove all of these fields from the calendar profile.

Forall item In calendarProfile.Items

	If( Lcase$(Left$(item.Name,15)) = "$filterformula_" ) Then

		Print "Cleanup " & item.Name

		Call item.Remove

	End If

End Forall

'Save changes to the calendar profile.

Call calendarProfile.Save( False, False )

'Disable all Rules.

Dim mailrule As NotesDocument

Set mailrule = folder.GetFirstDocument

While Not( mailrule Is Nothing )

	Call mailrule.ReplaceItemValue( "Enable","0" )

	Call mailrule.Save( True,False,True )

	

	Set mailrule = folder.GetNextDocument( mailrule )

Wend

'Open the Rules folder

Call workspace.OpenDatabase( db.Server, db.FilePath, "(Rules)" )

'Message to the user.

Messagebox "Cleanup complete."

End Sub

5

Subject: Thanks

Thank you for the code, everything is ok now

Olivier PICARD